SPARQL

ANNO Documentation

SPARQL

Endpoint

https://lod.onb.ac.at/sparql/anno

newspaper or periodical with subject heading "Verkehr"

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT DISTINCT ?dc_title
WHERE {?subjectURI dc:subject ?gnd_reference .
       ?subjectURI dc:title ?dc_title .
       ?gnd_reference skos:prefLabel "Verkehr"}

first pages of newspaper or periodical with subject heading "Verkehr"

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX edm: <http://www.europeana.eu/schemas/edm/>
SELECT ?first_page_link ?dc_title ?dc_date
WHERE {?subjectURI dc:subject ?gnd_reference .
       ?subjectURI dc:title ?dc_title .
       ?subjectURI dc:date ?dc_date .
       ?subjectURI edm:isShownBy ?first_page_link .
       ?gnd_reference skos:prefLabel "Verkehr"}

pdfs of newspaper or periodical with subject heading "Verkehr"

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX edm: <http://www.europeana.eu/schemas/edm/>
SELECT ?pdf_link
WHERE {?subjectURI dc:subject ?gnd_reference .
       ?subjectURI edm:hasView ?pdf_link .
       ?pdf_link dc:format "application/pdf" .
       ?gnd_reference skos:prefLabel "Verkehr"}

images of newspaper or periodical with subject heading "Verkehr"

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX edm: <http://www.europeana.eu/schemas/edm/>
SELECT ?image_link
WHERE {?subjectURI dc:subject ?gnd_reference .
       ?subjectURI edm:hasView ?image_link .
       ?image_link dc:format "image/jpeg" .
       ?gnd_reference skos:prefLabel "Verkehr"}

GND reference of all subject headings

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT DISTINCT ?dc_subject
WHERE {[] dc:subject ?dc_subject}
ORDER BY ASC(?dc_subject)

languages

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT DISTINCT ?dc_language
WHERE {[] dc:language ?dc_language}
ORDER BY ASC(?dc_language)

newspaper or periodical whose title starts with "Allgemein"

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT DISTINCT ?dc_title
WHERE {[] dc:title ?dc_title .
         FILTER regex(?dc_title,'^Allgemein')}
ORDER BY ASC(?dc_title)

newspaper whose title starts with "Allgemein"

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT DISTINCT ?dc_title
WHERE {?x dc:type "newspaper" .
       ?x dc:title ?dc_title .
         FILTER regex(?dc_title,'^Allgemein')}
ORDER BY ASC(?dc_title)

Core EDM resources

edm:ProvidedCHO

Properties Value
dc:date issue date of the newspaper or periodical
dc:identifier identifier of the newspaper or periodical
dc:type newspaper or periodical
dc:subject GND reference, connecting to a resource of type skos:Concept
dcterms:spatial GND reference, connecting to a resource of type skos:Concept
dc:language language
dc:title title as shown on http://anno.onb.ac.at/
edm:type always 'TEXT'
edm:rights if older than 140 years http://creativecommons.org/publicdomain/mark/1.0/ else http://rightsstatements.org/vocab/CNE/1.0/

ore:Aggregation

Properties Value
edm:isShownAt link to the issue on the ANNO Homepage
edm:provider always 'Austrian National Library'
edm:isShownBy links to the first page and is described in edm:WebResource
edm:hasView links to the following pages and is described in edm:WebResource

edm:WebResource for digital representations

periodical (not IIIF)

Properties Value
dc:description structure-info of the page
dc:format always 'image/jpeg'
edm:isNextInSequence link to previous page

newspaper (not IIIF)

Properties Value
dc:format image/jpeg
edm:isNextInSequence link to previous page
Properties Value
dc:format application/pdf

periodical (IIIF)

Properties Value
dc:description structure-info of the page
sioc:has_service connecting the WebResource to a resource of type sioc:Service
dcterms:isReferencedBy connects to a IIIF manifest URI
edm:isNextInSequence link to previous page

newspaper (IIIF)

Properties Value
sioc:has_service connecting the WebResource to a resource of type sioc:Service
dcterms:isReferencedBy connects to a IIIF manifest URI
edm:isNextInSequence link to previous page
Properties Value
dc:format application/pdf

Classes for contextual resources

skos:Concept

Properties Value
skos:prefLabel preferred label for GND referene

sioc:Service

Properties Value
dcterms:conformsTo indicating that the WebService conforms to the IIIF profile
doap:implements indicating that the WebService implements the IIIF protocol